Como usar no-ip para acesso remoto ao Mikrotik.

Download PDF

Olá pessoal!

Vejo que muitas pessoas ficam com dúvida de como fazer para ter acesso externo ao Mikrotik então ai vai um tutorial simples de como resolver esse problema.

 

Primeiramente você deve ter uma conta registrada no no-ip.org
Após se cadastrar, você terá que criar um direcionamento dentro do no-ip.

No seu Mikrotik você deverá criar o seguinte Script:

# DNS Dinâmico usando No-IP

#--------------- Altere os valores abaixo com suas informações corretas ------------------

# Conta de Usuário e Senha do No-IP
:local noipuser "usuario_No-IP"
:local noippass "senha_No-IP"

# Especifique o endereço do seu no-ip a ser usado
:local noiphost "seu_endereço_No-IP.com"

# Coloque aqui o nome de sua interface WAN (INTERNET)
:local inetinterface "Sua_Interface_WAN"

#------------------------------------------------------------------------------------
# Não mude mais nada daqui em diante!

:global previousIP

:if ([/interface get $inetinterface value-name=running]) do={
# Get the current IP on the interface
   :local currentIP [/ip address get [find interface="$inetinterface" disabled=no] address]

# Strip the net mask off the IP address
   :for i from=( [:len $currentIP] - 1) to=0 do={
       :if ( [:pick $currentIP $i] = "/") do={ 
           :set currentIP [:pick $currentIP 0 $i]
       } 
   }

   :if ($currentIP != $previousIP) do={
       :log info "No-IP: Current IP $currentIP is not equal to previous IP, update needed"
       :set previousIP $currentIP

# The update URL. Note the "\3F" is hex for question mark (?). Required since ? is a special character in commands.
       :local url "http://dynupdate.no-ip.com/nic/update\3Fmyip=$currentIP"
       :local noiphostarray
       :set noiphostarray [:toarray $noiphost]
       :foreach host in=$noiphostarray do={
           :log info "No-IP: Sending update for $host"
           /tool fetch url=($url . "&hostname=$host") user=$noipuser password=$noippass mode=http dst-path=("no-ip_ddns_update-" . $host . ".txt")
           :log info "No-IP: Host $host updated on No-IP with IP $currentIP"
       }
   }  else={
       :log info "No-IP: Previous IP $previousIP is equal to current IP, no update needed"
   }
} else={
   :log info "No-IP: $inetinterface is not currently running, so therefore will not update."
}

Após montar esse script, teremos que montar uma chamada constante para verificar a renovação do endereço de ip ou qualquer atualização do mesmo de forma simples.

Basta criar este scheuduler:

/system scheduler add comment="Atualização do No-IP" disabled=no interval=5m \
name=no-ip_ddns_update on-event=no-ip_ddns_update policy=read,write,test

 

E com isso você terá acesso fácil externamente ao seu Mikrotik tanto em RouterBoards como em PC´s Servers.

Em caso de dúvidas, use o texto original da própria Mikrotik clicando aqui

Administrador AcessoWi-Fi.com – Gerente UnicoHost Soluções Web – Engenheiro de Redes

Julio Rossoni

Administrador AcessoWi-Fi.com - Gerente UnicoHost Soluções Web - Engenheiro de Redes

This site uses Akismet to reduce spam. Learn how your comment data is processed.